ClearAttributes[Conjugate,Protected];Format[Conjugate[x_]]:=OverBar@x;SetAttributes[Conjugate,Protected];
SetOptions[$FrontEndSession,ShowCellLabel->False]

Content of the course:

Lecture 1: Spin networks and geometric operators

Lecture 2: Geometric interpretation of LQG

Lecture 3: Elements of spin foams

Numerical methods in LQG

Lecture 1: Spin networks and geometric operators

Content -
	Warmup with SU(2) 
	LQG Hilbert space
	Intertwiners
	Volume Operator

Minimal references -
	[(HyperlinkURL["BOOK", http://www.cpt.univ-mrs.fr/~rovelli/IntroductionLQG.pdf])] Rovelli and Vidotto, “Covariant Loop Quantum Gravity”
	[(HyperlinkURL["VIDEO", https://www.youtube.com/channel/UCZ4fso22jORv9aeGc9dEAxw])] Rovelli, “Introduction to Loop Quantum gravity” 
	[(HyperlinkURL["PAPER", https://arxiv.org/abs/1902.08439])] Martin-Dussaud, “A Primer of Group Theory for Loop Quantum Gravity and Spin-foams”

Warming up with SU(2)

SU(2) is the group of unitary complex matrices  with determinant 1. We parametrize any SU(2) matrix with 2 complex numbers and 1 constraint or equivalently 3 real variables.

U={{a,-Conjugate[b]},{b,Conjugate[a]}};

MatrixForm[U]

Det[U]==1

Exercise

Verify that U is unitary.

Experiment

Solution

MatrixForm[Inverse[U]/.Det[U]->1]

MatrixForm[ConjugateTranspose[U]]

A convenient parametrization are the Euler angles. Any SU(2) matrix  can be written in terms of three angles , ,

$Assumptions= {0≤ϕ≤ 2π,0≤θ≤π,0≤ψ≤4π};

UEuler[ϕ_,θ_,ψ_] := MatrixExp[I (-ϕ/2) PauliMatrix[3]].MatrixExp[-I (θ/2) PauliMatrix[2]].MatrixExp[I (-ψ/2) PauliMatrix[3]];

MatrixForm[UEuler[ϕ,θ,ψ]]

FullSimplify[Det[UEuler[ϕ,θ,ψ]]]

MatrixForm[FullSimplify[Inverse[UEuler[ϕ,θ,ψ]]]]

MatrixForm[FullSimplify[ConjugateTranspose[UEuler[ϕ,θ,ψ]]]]

SU(2) representations

SU(2) irreducible representations  are labelled by the eigenvalues of the Casimir operator 
			
	  .   

A basis of  is labelled by the eigenvalues of the angular momentum in the (conventional) direction z

	 
			 
with .  The matrix elements of a group element in the representation  are given by	
	
	

 is called Wigner matrix. Mathematica has a built-in function to write  in terms of the Euler angles:

UW12=Table[WignerD[{1/2,m,n},ϕ,θ,ψ],{m,-1/2,1/2},{n,-1/2,1/2}];

MatrixForm[UW12]

UW1=Table[WignerD[{1,m,n},ϕ,θ,ψ],{m,-1,1},{n,-1,1}];

MatrixForm[UW1]

The character of a group representation is a function on the group that associates to each group element the trace of the corresponding matrix

Exercise

Use the definition of character to show that the dimension of the representation  is 2+1.

Experiment

Solution

d[j_]:=Sum[WignerD[{j,m,m},0,0,0],{m,-j,j}];

Table[{j,d[j], 2j+1},{j,1,10}]

Exercise (extra)

Prove the Weyl character formula for SU(2)

Integration on SU(2)

The Haar measure of SU(2)  is the only left and right invariant measure over the group 
		
	 	 .

We will assume that the Haar measure is normalized to 1. 
	
	

In terms of the Euler angles the Haar measure assumes the form

HaarIntegrate[f_]:=Integrate[f Sin[θ]/(16π^2),{θ,0,π},{ϕ,0,2π},{ψ,0,4π}]

A measure on the group allows us to consider the Hilbert space .

Theorem. (Peter-Weyl)

The matrix elements  of the Wigner matrices, seen as functions on SU(2), are an orthogonal basis of

Exercise

Test the orthogonality relation of the Wigner matrices.

Experiment

Solutions

jtest1=1/2;
jtest2=1/2;

Integral[m1_,m2_,n1_,n2_]:=HaarIntegrate[Conjugate[WignerD[{jtest1,m1,n1},ϕ,θ,ψ]]WignerD[{jtest2,m2,n2},ϕ,θ,ψ]]

Grid@Join[{{"m1","m2","n1","n2","Integral"}},Flatten[Table[{m1,m2,n1,n2,Integral[m1,m2,n1,n2]},{m1,-jtest1,jtest1},{n1,-jtest1,jtest1},{m2,-jtest2,jtest2},{n2,-jtest2,jtest2}],3]]

Given a function  the Peter-Weyl theorem offers a notion of Fourier transform on the group.

		with

Exercise (extra)

Prove that the delta function over the group 

	
	
has the following Fourier transform

Solution

$Assumptions= {0<α<2π,L>0,L∈Integers};

It follows immediately from the definition 
	
	 .

Moreover, we can verify that

δ=FullSimplify[Sum[(2j+1)Sin[(2j+1)α]/Sin[α],{j,0,L,1/2}]]

For  corresponding to

Limit[δ,α->0]

The delta function diverge (cubically) with the cutoff. Remember: the delta is a distribution. On the other hand, for any other group element   since the two terms in the parenthesis cancel in the limit  .

The Kinematical Hilbert space of Loop Quantum Gravity

The Kinematical Hilbert space of LQG at fixed graph  with L links and N nodes is 
			

A spin network is a basis of : 
	1) Assign a spin  to each link of the graph. Notation  the SU(2) irrep of spin 
	2) Assign a Wigner matrix element to each link 
	3) Assign one invariant tensor (intertwiner) to each node
	4) Contract the Wigner matrix elements and intertwiners following the connectivity of the graph. 

Spin networks are eigenstates of the geometric operators.

Given a spin network state   and a surface S that intersect  on just one link  
	
	

where  is (related to) the area gap of the theory and for simplicity of notation we will set it to unity.

Question

What about the volume operator?

Intertwiners - 3 valent nodes

The intertwiner space of 3-valent nodes is

Exercise

Prove that if , , and  satisfy the triangular inequalities  
	
	 ,
	
then

Experiment

Solution

Using the composition of angular momentum we have that 
	
	
	
When we tensor also , we look for the invariant subspace  for some element  of the sum. However, since the irreducible representation  appears only once in the sum and  requires  we conclude that  if and only if 
	
	 and .

The tensor in  is called the Wigner (3jm)-symbol and written as
	
	 .
	
Conveniently Mathematica has a built in function for these symbols :

ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}];

Exercise

Verify the invariance of the three valent intertwiner

Experiment

Solution

j1=1; j2=2;j3=2;

m1= 1;m2=-2;m3=1;

Sum[WignerD[{j1,m1,n1},ϕ,θ,ψ]WignerD[{j2,m2,n2},ϕ,θ,ψ]WignerD[{j3,m3,n3},ϕ,θ,ψ]ThreeJSymbol[{j1,n1},{j2,n2},{j3,n3}],{n1,-j1,j1},{n2,-j2,j2},{n3,-j3,j3}]//FullSimplify

ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}]

The warning is related to the fact that if   then also . If the magnetic indices do not sum to 0 the (3jm) symbol is conventionally defined as 0.

Exercise (extra)

Prove the following expression

Exercise

As a consistency check verify that

Experiment

Solution

{j1, j2,j3}={3,2,3};

Sum[ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}]ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}],{m1,-j1,j1},{m2,-j2,j2},{m3,-j3,j3}]//FullSimplify

HaarIntegrate[f_]:=Integrate[f Sin[θ]/(16π^2),{θ,0,π},{ϕ,0,2π},{ψ,0,4π}]

Chi[j_] := Sum[WignerD[{j,m,m},ϕ,θ,ψ],{m,-j,j}]

HaarIntegrate[Chi[j1]Chi[j2]Chi[j3]]

This integration is very slow. Can we improve it? Let’s examine the object we are trying to integrate

test=TrigExpand[Sin[θ]/(16π^2)Chi[j1]Chi[j2]Chi[j3]];

the expression is very long. Let’s focus on two pieces at random to understand the general form

test[[2;;3]]

We can integrate each term of the sum independently. Notice that the integrals factorize and 
 unless  where .
There fore we can define

IntegralPhiPsi[X_]:=8π^2 Select[X,FreeQ[#,ϕ]&&FreeQ[#,ψ]&]

test2=IntegralPhiPsi[test]//TrigExpand;

We need only to perform the integral over  that is of the form 
 ,
therefore we can define:

IntegralTheta[X_]:=Module[{a,b,coeff},
a=Exponent[X,Cos[θ/2]];
b=Exponent[X,Sin[θ/2]];
coeff=ReplaceAll[θ->π/2][X]2^(a/2+b/2);
Return[coeff((Gamma[((1+a)/2)] Gamma[((1+b)/2)])/(Gamma[(1/2) (2+a+b)]))];]

IntegralTheta/@test2

Or for short

IntegralTheta/@TrigExpand[IntegralPhiPsi[test]]

Intertwiners - 4 valent nodes

The intertwiner space of 4-valent nodes is 

			
	
The recoupling basis of  can be written in terms of two three valent intertwiners:

Exercise (extra)

Verify the invariance of . Are these tensors normalized? Discuss the change of scheme: what happen if I couple the spins differently?

The projector to  in terms of integrals over SU(2) reads:

Exercise

Verify that the dimension of   is

Experiment

Solution

In analogy with the three valent case we notice that

{j1,j2,j3,j4}={3,2,3,4}

test=Sin[θ]/(16π^2)Chi[j1]Chi[j2]Chi[j3]Chi[j4]//TrigExpand;

IntegralTheta/@Expand[IntegralPhiPsi[test]]

Min[j1+j2,j3+j4]-Max[Abs[j1-j2],Abs[j3-j4]]+1

FourJSymbol12[{j1_,m1_},{j2_,m2_},{j3_,m3_},{j4_,m4_},j12_]:=(-1)^(j12+m1+m2)ThreeJSymbol[{j1,m1},{j2,m2},{j12,-m1-m2}]ThreeJSymbol[{j12,m1+m2},{j3,m3},{j4,m4}]

Sum[(2j12 +1)Sum[FourJSymbol12[{j1,m1},{j2,m2},{j3,m3},{j4,m4},j12]^2,{m1,-j1,j1},{m2,-j2,j2},{m3,-j3,j3},{m4,-j4,j4}],{j12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]}]

The volume operator

Note

The generalization of everything we said to arbitrary valence is straightforward.

We introduce the Dirac notation for a vector in the intertwiner space

Exercise

Compute the spectrum of the operator  where  are the generators of the representation of the link i.

Experiment

Solution

We start by observing that . The matrix elements of Q can be computed as 
	

If we change recoupling basis inserting two resolution of the identity also the matrix elements of  are easy to compute.


The change of basis coefficient are easy to compute numerically

{j1,j2,j3,j4}={1/2,1/2,1/2,1/2}

FourJSymbol13[{j1_,m1_},{j2_,m2_},{j3_,m3_},{j4_,m4_},j13_]:=(-1)^(j13+m1+m3)ThreeJSymbol[{j1,m1},{j3,m3},{j13,-m1-m3}]ThreeJSymbol[{j13,m1+m3},{j2,m2},{j4,m4}]

Do[ scal[j12,j13]=Sum[FourJSymbol12[{j1,m1},{j2,m2},{j3,m3},{j4,m4},j12]FourJSymbol13[{j1,m1},{j2,m2},{j3,m3},{j4,m4},j13],{m1,-j1,j1},{m2,-j2,j2},{m3,-j3,j3},{m4,-j4,j4}],{j12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]},{j13,Max[Abs[j1-j3],Abs[j2-j4]],Min[j1+j3,j2+j4]}]

Notice that we need to normalize the states and the (4jm) symbols are not normalized to 1 but to

matrixelement[j12_,j12p_]:=Sum[Sqrt[(2j12p+1)(2j12+1)](2j13+1)1/2(j13(j13+1)-j1(j1+1)-j3(j3+1))scal[j12,j13]Conjugate[scal[j12p,j13]],{j13,Max[Abs[j1-j3],Abs[j2-j4]],Min[j1+j3,j2+j4]}]//FullSimplify

Q[j12_,j12p_]:=1/2(j12(j12+1)-j12p(j12p+1))matrixelement[j12,j12p]

QMatrix= Table[Q[j12,j12p],{j12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]},{j12p,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]}]

spectrumQ=Eigenvalues[QMatrix]

Exercise

Compute the spectrum of the volume operator on 4-valent nodes

Experiment

Solution

Notice that the operator Q we just studied is related to the volume operator is 
	
	
	
Therefore the spectrum of the volume operator is directly related to the spectrum of Q.

Exercise (extra)

Discuss the eigenvalues of the volume operators.

Exercise (open problem)

Prove the existence of the volume gap.