SetOptions[GraphicsGrid,ImageSize->800];
SetOptions[ListPlot,ImageSize->Full];
SetOptions[ListLogLogPlot,ImageSize->Full];
ReconstructTetrahedron[j1_,j2_,j3_,j4_][{θ12_,τ12_}]:= Module[{n1,n2,n3,n4,n3tmp,n4tmp,h,v1,v2,v3,v4,a,b,x,y,z},
n1 = {1,0,0};
n2 = {Cos[θ12],Sin[θ12],0};
n4tmp=-1/j4{a,b,0}/.First@NSolve[{Norm[n1 j1 + n2 j2-{a,b,0}]==j3,Norm[{a,b,0}]==j4}];
n3tmp =- 1/j3(n1 j1 +n2 j2 +n4tmp j4);
n3 = RotationTransform[τ12,Normalize[j1 n1+ j2 n2]][n3tmp];
n4 = RotationTransform[τ12,Normalize[j1 n1+ j2 n2]][n4tmp];
{v1,v2,v3,v4}=Flatten[{x,y,z}/.Solve[#,{x,y,z}]&/@Subsets[{n1.{x,y,z}==0,n2.{x,y,z}==0,n3.{x,y,z}==0,n4.{x,y,z}==h},{3}],1];
Return[{{n1,n2,n3,n4},Tetrahedron[{v1,v2,v3,v4}/.Last@NSolve[Cross[v2-v1,v3-v1].Cross[v2-v1,v3-v1]==j1^2,Reals]]}]
]
RandomSphere[]:=Normalize[Table[RandomVariate[NormalDistribution[]],3]];
PhiTheta[n_]:={ArcTan[n[[1]]/Sqrt[1-n[[3]]^2],n[[2]]/Sqrt[1-n[[3]]^2]],ArcCos[n[[3]]]}
FourJSymbol12[{j1_,m1_},{j2_,m2_},{j3_,m3_},{j4_,m4_},j12_]:=(-1)^(j12+m1+m2)ThreeJSymbol[{j1,m1},{j2,m2},{j12,-m1-m2}]ThreeJSymbol[{j12,m1+m2},{j3,m3},{j4,m4}]
FourJSymbol13[{j1_,m1_},{j2_,m2_},{j3_,m3_},{j4_,m4_},j13_]:=(-1)^(j13+m1+m3)ThreeJSymbol[{j1,m1},{j3,m3},{j13,-m1-m3}]ThreeJSymbol[{j13,m1+m3},{j2,m2},{j4,m4}]
semiclassical[xint_]:={Line[{{xint,0},{xint,0.1}}]}

Numerical methods in LQG

Lecture 2: Geometric interpretation of LQG

Content -
	Geometric interpretation
	Phase space of classical polyhedra
	Geometric interpretation intertwiner space
	Coherent intertwiners
	

Minimal references -
	[(HyperlinkURL["BOOK", http://www.cpt.univ-mrs.fr/~rovelli/IntroductionLQG.pdf])] Rovelli and Vidotto, “Covariant Loop Quantum Gravity”
	[(HyperlinkURL["BOOK", http://link.springer.com/book/10.1007/978-3-642-61629-7])] Perelomov, “Generalized coherent states and their applications”
	[(HyperlinkURL["VIDEO", https://www.youtube.com/channel/UCZ4fso22jORv9aeGc9dEAxw])] Rovelli, “Introduction to Loop Quantum gravity”
	[(HyperlinkURL["PAPER", https://arxiv.org/abs/0705.0674])] Livine, and Speziale “A new spinfoam vertex for quantum gravity”
	[(HyperlinkURL["PAPER", https://arxiv.org/abs/1009.3402])] Bianchi, Dona, and Speziale “Polyhedra in loop quantum gravity”

Geometric interpretation

Each node of the graph  represent a chunk of (quantum) space.

Exercise

Show that the invariance condition for a generic intertwiner  (omitting the indices)

	

is equivalent to the closure condition 

	

where  are the SU(2) generators in the corresponding representation of spin .

Experiment

Solution

Consider a group element in a neighbourhood of the identity. Using the exponential map between SU(2) and its algebra
	
	

where  are the generator of SU(2). In the representation of spin  the

	
	
where  are the SU(2) generators in the representation of spin . By taking U in the invariance equation near the identity and expanding at the first order in  we obtain (omitting the indices)
	
	
	
which reduces to

Theorem - Minkowski 1897

Given a set of unit vectors  with , and a set of positive numbers  such that , there is a unique convex polyhedron with F faces with areas  and normals .

Kapovich - Millson polygon

The closure condition

	

naturally select a polygon in 3D.

F=4;
An[0]={0,0,0};
Do[
An[f]=RandomReal[3]RandomSphere[];
startp[f]= Sum[An[i],{i,0,f-1}];
arrow[f]=Arrow[{startp[f],startp[f]+An[f]}];
,{f,1,F-1}]
An[F]=-Sum[An[i],{i,0,F-1}];startp[F]= Sum[An[i],{i,0,F-1}];
arrow[F]=Arrow[{startp[F],startp[F]+An[F]}];
Graphics3D[arrow/@Range[F]]

Question

The KM polygon is determined by how many variables (up to global 3D rotation)?

Discussion

The KM polygon have  degrees of freedom. We can easily identify them as  couples  where  are the lengths of the diagonals of the polygon and  the angle around them.

F=4;
An[0]={0,0,0};
Do[
An[f]=RandomReal[3]RandomSphere[];
startp[f]= Sum[An[i],{i,0,f-1}];
arrow[f]=Arrow[{startp[f],startp[f]+An[f]}];
,{f,1,F-1}]
An[F]=-Sum[An[i],{i,0,F-1}];startp[F]= Sum[An[i],{i,0,F-1}];
arrow[F]=Arrow[{startp[F],startp[F]+An[F]}];
Do[
triangle[f] =Polygon[{An[0],startp[f-1]+An[f-1],startp[f]+An[f]}];
diagonals[f]=Arrow[{An[0],startp[f]+An[f]}];
,{f,2,F-2}]
triangle[F-1] =Polygon[{An[0],startp[F-2]+An[F-2],startp[F-1]+An[F-1]}];
Graphics3D[{arrow/@Range[F],{Opacity[0.8],LightGray,triangle/@Range[2,F-1]},{Red,diagonals/@Range[2,F-2]}}]

Discussion

The set of convex polyhedra with F faces with fixed areas  have  degrees of freedom. The tetrahedron with fixed areas have 2 degrees of freedom. 

One is related to a dihedral angle.
	
	

the other is related to the twist angle

	


The explicit geometric reconstruction is very complex in the case of general variance.

Graphics3D[{Red,Last@ReconstructTetrahedron[1,1,1,1][{ArcCos[-1/3],π/2}]}]

Geometric interpretation of the intertwiner space

These theorems suggest a geometrical interpretation of the (intertwiners) chunk of space as quantum polyhedra with face areas .


F = 4 	    F = 5          F = 6    ?

Dihedral angle operator 

	

The intertwiner in the recoupling base is an eigenvector a dihedral angle operator.

Question

Can we interpret the intertwiner  as a quantum tetrahedron?

Discussion

The interpretation of  as a sharp tetrahedron fails. The intertwiner cannot be eigenvector of all dihedral angles operator at the same time since

SU(2) coherent states

An SU(2) coherent state  is defined as 
	
	 	such that 	

The scalar product of an SU(2) coherent state with the usual basis  where  is the SU(2) group element corresponding to the rotation of the z axis into the direction . In terms of the Euler angles  where  are the spherical angles of .

Exercise

Prove that the SU(2) coherent state  saturates the Heisenberg relations in the directions orthogonal to .

Experiment

Solution

First of all compute the expectation value of   
	
	  if   is orthogonal to .

Moreover,

	

for any  orthogonal to  since the state  is invariant under any rotation with direction . Therefore,
	
Concluding that, if   is orthogonal to ,

Exercise

Prove that the SU(2) coherent states form an overcomplete basis of

Experiment

Solution

j=2;

SphereIntegrate[X_]:=1/(4π) Integrate[X Sin[θ],{ϕ,0,2π},{θ,0,π}]

(2 j +1)Table[SphereIntegrate[Conjugate[WignerD[{j,m,j},ϕ,θ,-ϕ]]WignerD[{j,n,j},ϕ,θ,-ϕ]],{m,-j,j},{n,-j,j}]

Livine - Speziale coherent intertwiners

A coherent intertwiner is the projection of the tensor product of SU(2) coherent states.
	
	

where   .

Exercise

Study the distribution  as a function of the intertwiner .

Experiment

Solution

{j1,j2,j3,j4}=10{1,1,1,1};

{{n1,n2,n3,n4},tet}=N@ReconstructTetrahedron[j1,j2,j3,j4][{1,π/2}];

Graphics3D[{Red,tet}]

{{ϕ1,θ1},{ϕ2,θ2},{ϕ3,θ3},{ϕ4,θ4}}=PhiTheta/@{n1,n2,n3,n4};
distro=Table[{j12,Sum[FourJSymbol12[{j1,m1},{j2,m2},{j3,m3},{j4,-m1-m2-m3},j12]WignerD[{j1,m1,j1},ϕ1,θ1,-ϕ1]WignerD[{j2,m2,j2},ϕ2,θ2,-ϕ2]WignerD[{j3,m3,j3},ϕ3,θ3,-ϕ3]WignerD[{j4,-m1-m2-m3,j4},ϕ4,θ4,-ϕ4],{m1,-j1,j1},{m2,-j2,j2},{m3,Max[-j3,-m1-m2-j4],Min[j3,j4-m1-m2]}]},{j12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]}];

The “semi-classical” value for the intertwiner corresponding to the dihedral angle 12 is

Int= j1(j1+1)+ j2(j2+1) +2 Sqrt[j1(j1+1)]Sqrt[j2(j2+1)]n1.n2;
xint=First[x/.Solve[{x^2+x-Int==0,x>0}]]

ListPlot[Abs[distro],Epilog->semiclassical[xint]]

Exercise

Notice that 

	
	
where

	
	
The coherent intertwiner do not depend on the basis of the projection.

Study the distribution  as a function of the intertwiner .

Experiment

Solution

distro13=Table[{j13,Sum[FourJSymbol13[{j1,m1},{j2,m2},{j3,m3},{j4,-m1-m2-m3},j13]WignerD[{j1,m1,j1},ϕ1,θ1,-ϕ1]WignerD[{j2,m2,j2},ϕ2,θ2,-ϕ2]WignerD[{j3,m3,j3},ϕ3,θ3,-ϕ3]WignerD[{j4,-m1-m2-m3,j4},ϕ4,θ4,-ϕ4],{m1,-j1,j1},{m2,-j2,j2},{m3,Max[-j3,-m1-m2-j4],Min[j3,j4-m1-m2]}]},{j13,Max[Abs[j1-j3],Abs[j2-j4]],Min[j1+j3,j2+j4]}];

The “semi-classical” value for the intertwiner corresponding to the dihedral angle 12 is

Int= j1(j1+1)+ j3(j3+1) +2 Sqrt[j1(j1+1)]Sqrt[j3(j3+1)]n1.n3;
xint13=First[x/.Solve[{x^2+x-Int==0,x>0}]]

ListPlot[Abs[distro13],Epilog->semiclassical[xint13]]

Exercise

Verify that coherent intertwiners form an overcomplete basis of the intertwiner space
	
where the measure is the product of the measure over 4 copies of a 2-sphere.

Experiment

Solution

{j1,j2,j3,j4}={1,1,1,1}

IntegralPhi4[X_]:= (2π)^4Select[X,FreeQ[#,ϕ1]&&FreeQ[#,ϕ2]&&FreeQ[#,ϕ3]&&FreeQ[#,ϕ4]&]

coeff[j12_]:=Sum[FourJSymbol12[{j1,m1},{j2,m2},{j3,m3},{j4,-m1-m2-m3},j12]WignerD[{j1,m1,j1},ϕ1,θ1,-ϕ1]WignerD[{j2,m2,j2},ϕ2,θ2,-ϕ2]WignerD[{j3,m3,j3},ϕ3,θ3,-ϕ3]WignerD[{j4,-m1-m2-m3,j4},ϕ4,θ4,-ϕ4],{m1,-j1,j1},{m2,-j2,j2},{m3,-j3,j3}]

conjcoeff[j12_]:=Sum[FourJSymbol12[{j1,m1},{j2,m2},{j3,m3},{j4,-m1-m2-m3},j12]WignerD[{j1,m1,j1},-ϕ1,θ1,ϕ1]WignerD[{j2,m2,j2},-ϕ2,θ2,ϕ2]WignerD[{j3,m3,j3},-ϕ3,θ3,ϕ3]WignerD[{j4,-m1-m2-m3,j4},-ϕ4,θ4,ϕ4],{m1,-j1,j1},{m2,-j2,j2},{m3,-j3,j3}]

measure= (2j1+1) 2 Cos[θ1/2] Sin[θ1/2] (2j2+1) 2 Cos[θ2/2] Sin[θ2/2] (2j3+1) 2 Cos[θ3/2] Sin[θ3/2] (2j4+1) 2 Cos[θ4/2] Sin[θ4/2];

Table[1/(4π)^4Integrate[Expand[IntegralPhi4[Expand[coeff[j12]conjcoeff[k12]measure]]],{θ1,0,π},{θ2,0,π},{θ3,0,π},{θ4,0,π}],{j12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]},{k12,Max[Abs[j1-j2],Abs[j3-j4]],Min[j1+j2,j3+j4]}]